Udl Erzeugen
Zuletzt geändert: 14.03.2026 17:34

UDL-Datei erzeugen (VBScript) #

Eine UDL-Datei (Universal Data Link) speichert ADO-Verbindungszeichenfolgen und wird von EULANDA zum Zugriff auf die Mandantendatenbank verwendet. Normalerweise erzeugt man UDL-Dateien über den Windows-Dialog, aber per VBScript lässt sich das auch programmatisch erledigen.

Hintergrund #

Eine UDL-Datei ist im Grunde eine einfache Textdatei im Unicode-Format (UTF-16 LE mit BOM). Sie enthält einen festen Kopfbereich und den eigentlichen ADO-ConnectionString. Einen Einblick in den Aufbau erhält man z.B., indem man eine bestehende UDL-Datei mit dem Windows-Texteditor (notepad.exe) öffnet.

Zum programmgesteuerten Erzeugen wird das ADO-Stream-Objekt (ADODB.Stream) verwendet. Im Gegensatz zum Scripting.FileSystemObject schreibt es automatisch das Byte Order Mark (BOM) und unterstützt Unicode nativ.

Das Script #

Sub SaveUdlFile(ConnectionString, FileName)
Const adTypeText = 2
Const adSaveCreateOverWrite = 2

' Erzeugen des ADO-Stream-Objekts
Dim strm
Set strm = CreateObject("ADODB.Stream")

' Stream auf Unicode-Verarbeitung einstellen
strm.Type = adTypeText
strm.Charset = "Unicode"

strm.Open

' Schreiben der Daten in den Stream
' BOM (Byte Order Mark) muss nicht extra geschrieben werden,
' da dies das Stream-Objekt automatisch erledigt
strm.WriteText "[oledb]" & vbCrLf
strm.WriteText "; Everything after this line is an OLE DB initstring" & vbCrLf
strm.WriteText ConnectionString & vbCrLf

' Speichern als Datei
strm.SaveToFile FileName, adSaveCreateOverWrite

' Freigabe des Stream-Objekts
Set strm = Nothing

End Sub

Anwendungsbeispiel #

Dim sConn
sConn = "Provider=MSOLEDBSQL.1;" & _
        "Integrated Security=SSPI;" & _
        "Initial Catalog=EULANDA_MeinMandant;" & _
        "Data Source=.\SQLEXPRESS"

SaveUdlFile sConn, "C:\Eulanda\MeinMandant.udl"

WScript.Echo "UDL-Datei wurde erzeugt."

Nach dem Ausführen kann die erzeugte UDL-Datei direkt von EULANDA oder anderen ADO-basierten Anwendungen verwendet werden. Per Doppelklick auf die UDL-Datei öffnet sich der Windows-Verbindungsdialog, in dem die Einstellungen überprüft und getestet werden können.

Siehe auch #