Report-Dialoge #

Drei einfache Eingabedialoge für die Abfrage von Benutzereingaben in Berichten und Scripts. Sie werden über Client.CreateDialog erzeugt.

GetStringDlg #

Eingabedialog für eine einzelne Textzeile (ähnlich der VBScript-Funktion InputBox).

Set dlg = Client.CreateDialog("Report.GetStringDlg")

Eigenschaften #

Eigenschaft	Typ	Beschreibung
`Caption`	String	Fenstertitel
`Info`	String	Mehrzeiliger Informationstext im oberen Bereich
`Label1`	String	Bezeichnung des Eingabefeldes
`Value1`	String	Eingegebener Text

Beispiel #

Option Explicit

Dim s
With Client.CreateDialog("Report.GetStringDlg")
  .Caption = "Auswertung"
  .Info = "Bitte geben Sie den Titel der Auswertung ein"
  .Value1 = "Auswertung"
  .Label1 = "Titel"

  If .Execute Then
    s = .Value1
    MsgBox "Die Auswertung erhält den Titel " & vbCrLf & s
  Else
    MsgBox "Die Eingabe wurde abgebrochen"
  End If
End With

GetDateDlg #

Eingabedialog für ein oder zwei Datumsfelder.

Set dlg = Client.CreateDialog("Report.GetDateDlg")

Eigenschaften #

Eigenschaft	Typ	Beschreibung
`Caption`	String	Fenstertitel
`Info`	String	Mehrzeiliger Informationstext
`Label1`	String	Bezeichnung des ersten Datumsfeldes
`Value1`	Date	Erstes Datum
`Label2`	String	Bezeichnung des zweiten Datumsfeldes (leer = unterdrückt)
`Value2`	Date	Zweites Datum

Wird Label2 nicht gesetzt, erscheint nur ein Datumsfeld.

Beispiel #

Option Explicit

With Client.CreateDialog("Report.GetDateDlg")
  .Caption = "Auswertung"
  .Info = "Bitte geben Sie den Auswertungszeitraum an"
  .Value1 = Date
  .Label1 = "Ab Datum"
  .Value2 = Date
  .Label2 = "Bis Datum"

  If .Execute Then
    MsgBox "Zeitraum: " & vbCrLf & _
           "von: " & CStr(CDate(.Value1)) & vbCrLf & _
           "bis: " & CStr(CDate(.Value2))
  Else
    MsgBox "Die Eingabe wurde abgebrochen"
  End If
End With

GetOptionsDlg #

Auswahldialog für bis zu 6 Optionen (Checkboxen). Für mehr als 6 Optionen sollte der MultiSelect-Dialog verwendet werden.

Set dlg = Client.CreateDialog("Report.GetOptionsDlg")

Eigenschaften #

Eigenschaft	Typ	Beschreibung
`Caption`	String	Fenstertitel
`Info`	String	Mehrzeiliger Informationstext
`Label1` bis `Label6`	String	Bezeichnungen der Optionen
`Value1` bis `Value6`	Boolean	Zustand der jeweiligen Checkbox

Beispiel #

Option Explicit

With Client.CreateDialog("Report.GetOptionsDlg")
  .Caption = "Exportoptionen"
  .Info = "Bitte wählen Sie die zu exportierenden Daten aus"
  .Value1 = True
  .Label1 = "Artikel"
  .Label2 = "Adressen"
  .Label3 = "Aufträge"
  .Label4 = "Rechnungen"

  If .Execute Then
    Dim s
    s = ""
    If .Value1 Then s = s & "Artikel, "
    If .Value2 Then s = s & "Adressen, "
    If .Value3 Then s = s & "Aufträge, "
    If .Value4 Then s = s & "Rechnungen, "

    If s = "" Then
      s = "Keine Auswahl getroffen"
    Else
      s = Left(s, Len(s) - 2)
    End If

    MsgBox "Auswahl: " & s
  End If
End With