WebBrowser #

Der WebBrowser-Dialog zeigt ein Fenster mit eingebettetem Webbrowser. Er kann sowohl modal als auch nicht-modal angezeigt werden und eignet sich zur Darstellung von URL-Inhalten oder dynamisch erzeugtem HTML.

Set wb = Client.CreateDialog("WebBrowser")

Eigenschaften #

Eigenschaft	Typ	Zugriff	Beschreibung
`URL`	String	lesen/schreiben	URL, die geladen und angezeigt wird
`HTMLSource`	String	lesen/schreiben	HTML-Quelltext zur direkten Anzeige
`Width`	Integer	lesen/schreiben	Fensterbreite
`Height`	Integer	lesen/schreiben	Fensterhöhe
`Top`	Integer	lesen/schreiben	Obere Position
`Left`	Integer	lesen/schreiben	Linke Position
`Title`	String	lesen/schreiben	Fenstertitel
`SubTitle`	String	lesen/schreiben	Untertitel
`IconUrl`	String	lesen/schreiben	Symbol-URL
`BorderStyle`	Integer	lesen/schreiben	Rahmenstil
`AbortButtonVisible`	Boolean	lesen/schreiben	Abbrechen-Button anzeigen
`OKButtonVisible`	Boolean	lesen/schreiben	OK-Button anzeigen
`FormVisible`	Boolean	nur lesen	`True` wenn das Fenster noch sichtbar ist
`Document`	IDocument	nur lesen	Document-Objekt des Browsers
`Context`	Object	lesen/schreiben	Context-Objekt

Methoden #

Methode	Beschreibung
`Show`	Zeigt das Fenster nicht-modal an (Script läuft weiter)
`ShowModal`	Zeigt das Fenster modal an (Script wartet)
`Close`	Schließt das Fenster
`SetBounds(Left, Top, Width, Height)`	Setzt Position und Größe

Beispiele #

Einfaches Browserfenster #

Option Explicit

Dim wb
Set wb = Client.CreateDialog("WebBrowser")
wb.HTMLSource = "<html><h1>Hallo Welt</h1></html>"
wb.Width = 400
wb.Height = 150
wb.Show

Client.Properties anzeigen #

Option Explicit

Dim SL, SLOut, i, s, Html, wb
Set SL = Client.CreateObject("Eulanda.StringList")
Set SLOut = Client.CreateObject("Eulanda.StringList")

SL.Add ":EXE"
SL.Add "EXE.VERSION"
SL.Add "EXE.FULLVERSION"
SL.Add "EXE.UDLFILENAME"

SL.Add ":FOLDER"
SL.Add "FOLDER.DESKTOP"
SL.Add "FOLDER.WINDOWS"
SL.Add "FOLDER.EULANDATEMP"
SL.Add "FOLDER.CLIENT"

For i = 0 To SL.Count - 1
  s = SL.Strings(i)
  If Left(s, 1) <> ":" Then
    On Error Resume Next
    SLOut.Add "<b>" & s & "</b> " & Client.Properties(s)
    If Err.Number <> 0 Then
      SLOut.Add "<span style='color:red'>" & Err.Description & "</span>"
      Err.Clear
    End If
    On Error GoTo 0
  Else
    SLOut.Add ""
    SLOut.Add "<h3>" & Mid(s, 2) & "</h3>"
  End If
Next

Html = "<html><pre>" & SLOut.Text & "</pre></html>"

Set SL = Nothing
Set SLOut = Nothing

Set wb = Client.CreateDialog("WebBrowser")
wb.HTMLSource = Html
wb.Title = "Client.Properties()"
wb.IconUrl = "folder"
wb.BorderStyle = 5
wb.AbortButtonVisible = False
wb.ShowModal

Set wb = Nothing

Ein nicht-modales Fenster, das angezeigt wird, bis eine Bedingung eintritt:

Option Explicit

Dim wb
Set wb = Client.CreateDialog("WebBrowser")
wb.Title = "Verarbeitung"
wb.SubTitle = "einen Moment bitte ..."
wb.Height = 85
wb.Show

' Verarbeitung ...
ellib.Sleep 3000

' Fenster schließen wenn noch sichtbar
If wb.FormVisible Then
  wb.Close
End If

Set wb = Nothing

Siehe auch #

Interne Webseiten – Webseiten innerhalb von EULANDA